mirror of https://github.com/rusefi/rusefi.git
61 lines
1.9 KiB
Batchfile
61 lines
1.9 KiB
Batchfile
::::::::::::::::::::::::::::::::::::::::::::
|
|
:: Elevate.cmd - Version 4
|
|
:: Automatically check & get admin rights
|
|
:: see "https://stackoverflow.com/a/12264592/1016343" for description
|
|
::::::::::::::::::::::::::::::::::::::::::::
|
|
@echo off
|
|
CLS
|
|
ECHO.
|
|
ECHO =============================
|
|
ECHO Running Admin shell
|
|
ECHO =============================
|
|
|
|
:init
|
|
setlocal DisableDelayedExpansion
|
|
set cmdInvoke=1
|
|
set winSysFolder=System32
|
|
set "batchPath=%~dpnx0"
|
|
rem this works also from cmd shell, other than %~0
|
|
for %%k in (%0) do set batchName=%%~nk
|
|
set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"
|
|
setlocal EnableDelayedExpansion
|
|
|
|
:checkPrivileges
|
|
NET FILE 1>NUL 2>NUL
|
|
if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )
|
|
|
|
:getPrivileges
|
|
if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)
|
|
ECHO.
|
|
ECHO **************************************
|
|
ECHO Invoking UAC for Privilege Escalation
|
|
ECHO **************************************
|
|
|
|
ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"
|
|
ECHO args = "ELEV " >> "%vbsGetPrivileges%"
|
|
ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"
|
|
ECHO args = args ^& strArg ^& " " >> "%vbsGetPrivileges%"
|
|
ECHO Next >> "%vbsGetPrivileges%"
|
|
|
|
if '%cmdInvoke%'=='1' goto InvokeCmd
|
|
|
|
ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"
|
|
goto ExecElevation
|
|
|
|
:InvokeCmd
|
|
ECHO args = "/c """ + "!batchPath!" + """ " + args >> "%vbsGetPrivileges%"
|
|
ECHO UAC.ShellExecute "%SystemRoot%\%winSysFolder%\cmd.exe", args, "", "runas", 1 >> "%vbsGetPrivileges%"
|
|
|
|
:ExecElevation
|
|
"%SystemRoot%\%winSysFolder%\WScript.exe" "%vbsGetPrivileges%" %*
|
|
exit /B
|
|
|
|
:gotPrivileges
|
|
setlocal & cd /d %~dp0
|
|
if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul & shift /1)
|
|
|
|
::::::::::::::::::::::::::::
|
|
::START
|
|
::::::::::::::::::::::::::::
|
|
ECHO %batchName% Arguments: P1=%1 P2=%2 P3=%3 P4=%4 P5=%5 P6=%6 P7=%7 P8=%8 P9=%9
|
|
STM32Bootloader.bat |