Multi-region Cloud-SQL example

examples/data-solutions/cloudsql-multiregion/README.md

@@ -0,0 +1,24 @@
+# Cloud SQL instance with multi-region read replicas
+
+TBD
+
+<!-- BEGIN TFDOC -->
+
+## Variables
+
+| name | description | type | required | default |
+|---|---|:---:|:---:|:---:|
+| [prefix](variables.tf#L17) | Unique prefix used for resource names. Not used for project if 'project_create' is null. | <code>string</code> | ✓ |  |
+| [project_id](variables.tf#L31) | Project id, references existing project if `project_create` is null. | <code>string</code> | ✓ |  |
+| [regions](variables.tf#L36) | Map of instance_name => location where instances will be deployed. | <code>map&#40;string&#41;</code> | ✓ |  |
+| [project_create](variables.tf#L22) | Provide values if project creation is needed, uses existing project if null. Parent is in 'folders/nnn' or 'organizations/nnn' format. | <code title="object&#40;&#123;&#10;  billing_account_id &#61; string&#10;  parent             &#61; string&#10;&#125;&#41;">object&#40;&#123;&#8230;&#125;&#41;</code> |  | <code>null</code> |
+
+## Outputs
+
+| name | description | sensitive |
+|---|---|:---:|
+| [connection_names](outputs.tf#L17) | Connection name of each instance. |  |
+| [ips](outputs.tf#L22) | IP address of each instance. |  |
+| [project_id](outputs.tf#L27) | ID of the project containing all the instances. |  |
+
+<!-- END TFDOC -->

examples/data-solutions/cloudsql-multiregion/main.tf

@@ -0,0 +1,54 @@
+/**
+ * Copyright 2022 Google LLC
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *      http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+module "project" {
+  source          = "../../../modules/project"
+  name            = var.project_id
+  parent          = try(var.project_create.parent, null)
+  billing_account = try(var.project_create.billing_account_id, null)
+  project_create  = var.project_create != null
+  prefix          = var.project_create == null ? null : var.prefix
+  services = [
+    "servicenetworking.googleapis.com",
+  ]
+
+}
+
+module "vpc" {
+  source     = "../../../modules/net-vpc"
+  project_id = module.project.project_id
+  name       = "vpc"
+  psa_config = {
+    ranges = { cloud-sql = "10.60.0.0/16" }
+    routes = null
+  }
+}
+
+module "db" {
+  source           = "../../../modules/cloudsql-instance"
+  project_id       = module.project.project_id
+  network          = module.vpc.self_link
+  name             = "db"
+  region           = var.regions.primary
+  database_version = "POSTGRES_13"
+  tier             = "db-g1-small"
+
+  replicas = {
+    for name, region in var.regions :
+    name => region
+    if name != "primary"
+  }
+}

examples/data-solutions/cloudsql-multiregion/outputs.tf

@@ -0,0 +1,30 @@
+/**
+ * Copyright 2022 Google LLC
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *      http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+output "connection_names" {
+  description = "Connection name of each instance."
+  value       = module.db.connection_names
+}
+
+output "ips" {
+  description = "IP address of each instance."
+  value       = module.db.ips
+}
+
+output "project_id" {
+  description = "ID of the project containing all the instances."
+  value       = module.project.project_id
+}

examples/data-solutions/cloudsql-multiregion/variables.tf

@@ -0,0 +1,43 @@
+/**
+ * Copyright 2022 Google LLC
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *      http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+variable "prefix" {
+  description = "Unique prefix used for resource names. Not used for project if 'project_create' is null."
+  type        = string
+}
+
+variable "project_create" {
+  description = "Provide values if project creation is needed, uses existing project if null. Parent is in 'folders/nnn' or 'organizations/nnn' format."
+  type = object({
+    billing_account_id = string
+    parent             = string
+  })
+  default = null
+}
+
+variable "project_id" {
+  description = "Project id, references existing project if `project_create` is null."
+  type        = string
+}
+
+variable "regions" {
+  description = "Map of instance_name => location where instances will be deployed."
+  type        = map(string)
+  validation {
+    condition     = contains(keys(var.regions), "primary")
+    error_message = "Regions map must contain `primary` as a key."
+  }
+}

modules/cloudsql-instance/main.tf

@@ -19,6 +19,10 @@ locals {
   is_mysql     = can(regex("^MYSQL", var.database_version))
   has_replicas = try(length(var.replicas) > 0, false)
 
+  // Enable backup if the user asks for it or if the user is deploying
+  // MySQL with replicas
+  enable_backup = var.backup_configuration.enabled || (local.is_mysql && local.has_replicas)
+
   users = {
     for user, password in coalesce(var.users, {}) :
     (user) => (
@@ -65,24 +69,25 @@ resource "google_sql_database_instance" "primary" {
       }
     }
 
-    backup_configuration {
-      // Enable backup if the user asks for it or if the user is
-      // deploying MySQL with replicas
-      enabled = var.backup_configuration.enabled || (local.is_mysql && local.has_replicas)
+    dynamic "backup_configuration" {
+      for_each = local.enable_backup ? { 1 = 1 } : {}
+      content {
+        enabled = true
 
-      // enable binary log if the user asks for it or we have replicas,
-      // but only form MySQL
-      binary_log_enabled = (
-        local.is_mysql
-        ? var.backup_configuration.binary_log_enabled || local.has_replicas
-        : null
-      )
-      start_time                     = var.backup_configuration.start_time
-      location                       = var.backup_configuration.location
-      transaction_log_retention_days = var.backup_configuration.log_retention_days
-      backup_retention_settings {
-        retained_backups = var.backup_configuration.retention_count
-        retention_unit   = "COUNT"
+        // enable binary log if the user asks for it or we have replicas,
+        // but only for MySQL
+        binary_log_enabled = (
+          local.is_mysql
+          ? var.backup_configuration.binary_log_enabled || local.has_replicas
+          : null
+        )
+        start_time                     = var.backup_configuration.start_time
+        location                       = var.backup_configuration.location
+        transaction_log_retention_days = var.backup_configuration.log_retention_days
+        backup_retention_settings {
+          retained_backups = var.backup_configuration.retention_count
+          retention_unit   = "COUNT"
+        }
       }
     }