|
||
---|---|---|
.. | ||
README.md | ||
groups.tf | ||
health-check.tf | ||
main.tf | ||
outputs.tf | ||
variables.tf | ||
versions.tf |
README.md
Internal Load Balancer Module
This module allows managing a GCE Internal Load Balancer and integrates the forwarding rule, regional backend, and optional health check resources. It's designed to be a simple match for the compute-vm
module, which can be used to manage instance templates and instance groups.
Issues
TODO(ludoo): check if this is still the case after splitting out MIG from compute-vm
There are some corner cases (eg when switching the instance template from internal service account to an externally managed one) where Terraform raises a cycle error on apply. In these situations, run successive applies targeting resources used in the template first then the template itself, and the cycle should be fixed.
One other issue is a Provider produced inconsistent final plan
error which is sometimes raised when switching template version. This seems to be related to this open provider issue, but it's relatively harmless since the resource is updated, and subsequent applies raise no errors.
Examples
Reference existing MIGs
This example shows how to reference existing Managed Infrastructure Groups (MIGs).
module "instance_template" {
source = "./fabric/modules/compute-vm"
project_id = var.project_id
create_template = true
name = "vm-test"
service_account_create = true
zone = "europe-west1-b"
network_interfaces = [
{
network = var.vpc.self_link
subnetwork = var.subnet.self_link
}
]
tags = [
"http-server"
]
}
module "mig" {
source = "./fabric/modules/compute-mig"
project_id = var.project_id
location = "europe-west1"
name = "mig-test"
target_size = 1
instance_template = module.instance_template.template.self_link
}
module "ilb" {
source = "./fabric/modules/net-ilb"
project_id = var.project_id
region = "europe-west1"
name = "ilb-test"
service_label = "ilb-test"
vpc_config = {
network = var.vpc.self_link
subnetwork = var.subnet.self_link
}
backends = [{
group = module.mig.group_manager.instance_group
}]
health_check_config = {
http = {
port = 80
}
}
}
# tftest modules=3 resources=6
Externally managed instances
This examples shows how to create an ILB by combining externally managed instances (in a custom module or even outside of the current root module) in an unmanaged group. When using internally managed groups, remember to run terraform apply
each time group instances change.
module "ilb" {
source = "./fabric/modules/net-ilb"
project_id = var.project_id
region = "europe-west1"
name = "ilb-test"
service_label = "ilb-test"
vpc_config = {
network = var.vpc.self_link
subnetwork = var.subnet.self_link
}
group_configs = {
my-group = {
zone = "europe-west1-b"
instances = [
"instance-1-self-link",
"instance-2-self-link"
]
}
}
backends = [{
group = module.ilb.groups.my-group.self_link
}]
health_check_config = {
http = {
port = 80
}
}
}
# tftest modules=1 resources=4
End to end example
This example spins up a simple HTTP server and combines four modules:
nginx
from thecloud-config-container
collection, to manage instance configurationcompute-vm
to manage the instance template and unmanaged instance group- this module to create an Internal Load Balancer in front of the managed instance group
Note that the example uses the GCE default service account. You might want to create an ad-hoc service account by combining the iam-service-account
module, or by having the GCE VM module create one for you. In both cases, remember to set at least logging write permissions for the service account, or the container on the instances won't be able to start.
module "cos-nginx" {
source = "./fabric/modules/cloud-config-container/nginx"
}
module "instance-group" {
source = "./fabric/modules/compute-vm"
for_each = toset(["b", "c"])
project_id = var.project_id
zone = "europe-west1-${each.key}"
name = "ilb-test-${each.key}"
network_interfaces = [{
network = var.vpc.self_link
subnetwork = var.subnet.self_link
nat = false
addresses = null
}]
boot_disk = {
initialize_params = {
image = "projects/cos-cloud/global/images/family/cos-stable"
type = "pd-ssd"
size = 10
}
}
tags = ["http-server", "ssh"]
metadata = {
user-data = module.cos-nginx.cloud_config
}
group = { named_ports = {} }
}
module "ilb" {
source = "./fabric/modules/net-ilb"
project_id = var.project_id
region = "europe-west1"
name = "ilb-test"
service_label = "ilb-test"
vpc_config = {
network = var.vpc.self_link
subnetwork = var.subnet.self_link
}
ports = [80]
backends = [
for z, mod in module.instance-group : {
group = mod.group.self_link
balancing_mode = "UTILIZATION"
}
]
health_check_config = {
http = {
port = 80
}
}
}
# tftest modules=3 resources=7
Variables
name | description | type | required | default |
---|---|---|---|---|
name | Name used for all resources. | string |
✓ | |
project_id | Project id where resources will be created. | string |
✓ | |
region | GCP region. | string |
✓ | |
vpc_config | VPC-level configuration. | object({…}) |
✓ | |
address | Optional IP address used for the forwarding rule. | string |
null |
|
backend_service_config | Backend service level configuration. | object({…}) |
{} |
|
backends | Load balancer backends, balancing mode is one of 'CONNECTION' or 'UTILIZATION'. | list(object({…})) |
[] |
|
description | Optional description used for resources. | string |
"Terraform managed." |
|
global_access | Global access, defaults to false if not set. | bool |
null |
|
group_configs | Optional unmanaged groups to create. Can be referenced in backends via outputs. | map(object({…})) |
{} |
|
health_check | Name of existing health check to use, disables auto-created health check. | string |
null |
|
health_check_config | Optional auto-created health check configuration, use the output self-link to set it in the auto healing policy. Refer to examples for usage. | object({…}) |
{…} |
|
labels | Labels set on resources. | map(string) |
{} |
|
ports | Comma-separated ports, leave null to use all ports. | list(string) |
null |
|
protocol | IP protocol used, defaults to TCP. | string |
"TCP" |
|
service_label | Optional prefix of the fully qualified forwarding rule name. | string |
null |
Outputs
name | description | sensitive |
---|---|---|
backend_service | Backend resource. | |
backend_service_id | Backend id. | |
backend_service_self_link | Backend self link. | |
forwarding_rule | Forwarding rule resource. | |
forwarding_rule_address | Forwarding rule address. | |
forwarding_rule_id | Forwarding rule id. | |
forwarding_rule_self_link | Forwarding rule self link. | |
group_self_links | Optional unmanaged instance group self links. | |
groups | Optional unmanaged instance group resources. | |
health_check | Auto-created health-check resource. | |
health_check_self_id | Auto-created health-check self id. | |
health_check_self_link | Auto-created health-check self link. |