zcash-android-wallet-sdk/build.gradle

buildscript {
    ext.buildConfig = [
        'compileSdkVersion': 28,
        'minSdkVersion': 16,
        'targetSdkVersion': 28
    ]
    ext.versions = [
        'kotlin': '1.3.10',
        'architectureComponents': '2.0.0'
    ]
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.4.0-alpha05'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:${versions.kotlin}"
        classpath "com.github.ben-manes:gradle-versions-plugin:0.20.0"
        classpath 'com.github.dcendents:android-maven-gradle-plugin:2.1'
    }
}

apply from: 'custom-tasks.gradle'
apply plugin: 'com.android.library'
apply plugin: "kotlin-android-extensions"
apply plugin: "kotlin-android"
apply plugin: 'kotlin-kapt'
apply plugin: 'com.github.ben-manes.versions'
apply plugin: 'com.github.dcendents.android-maven'

group = 'cash.z.android.wallet'
version = '1.2.0'

repositories {
    google()
    jcenter()
}

android {
    compileSdkVersion 28

    defaultConfig {
        minSdkVersion 16
        targetSdkVersion 28
        versionCode = 1_02_00
        versionName = "1.2.0"
        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro"
        }
    }
    sourceSets {
        main {
            java {
                srcDirs "build/generated/source/wire"
            }
        }
    }
}

dependencies {
    // Square
    api "com.squareup.wire:wire-runtime:2.2.0"

    // Architecture components
    implementation "androidx.lifecycle:lifecycle-runtime:${versions.architectureComponents}"
    implementation "androidx.lifecycle:lifecycle-extensions:${versions.architectureComponents}"
    implementation "androidx.room:room-runtime:${versions.architectureComponents}"
    kapt "androidx.lifecycle:lifecycle-compiler:${versions.architectureComponents}"
    kapt "androidx.room:room-compiler:${versions.architectureComponents}"

    // Other
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:${versions.kotlin}"
    implementation "com.android.support:appcompat-v7:28.0.0"

    // Tests
    testImplementation "junit:junit:4.12"
    androidTestImplementation "androidx.test:runner:1.1.0"
    androidTestImplementation "androidx.test.espresso:espresso-core:3.1.0"
    androidTestImplementation "androidx.test:core:1.0.0"
    androidTestImplementation "androidx.arch.core:core-testing:${versions.architectureComponents}"
}


preBuild.dependsOn generateProtobufClasses
preBuild.dependsOn copyAllJniLibs